【Arduino】秋月AE-nRF52840を使う

#define IO_PIN    (0)

void setup()
{
  pinMode(IO_PIN, OUTPUT);
}

void loop()
{
  while(1)
  {
    digitalWrite(IO_PIN, HIGH);
    digitalWrite(IO_PIN, LOW);
  }
}

#define BUTTON_PIN    (12)
#define LED_PIN       (13)

void setup()
{
  pinMode(LED_PIN, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLDOWN);
}

void loop()
{
  digitalWrite(LED_PIN, digitalRead(BUTTON_PIN));
}

#define PWM_PIN     (14)

void setup()
{
  int16_t tblPWM[] = {1, 128, 254};
  int16_t tableCount = sizeof(tblPWM) / sizeof(int16_t);

  pinMode(PWM_PIN, OUTPUT);
  
  while(1)
  {
    for(int16_t i = 0; i < tableCount; i ++)
    {
      analogWrite(PWM_PIN, tblPWM[i]);
      delay(1000);
    }
  }
}

void loop()
{
}

#include <Adafruit_TinyUSB.h>

void setup()
{
  Serial.begin(115200);
  delay(1000);

  pinMode(A0, INPUT);

  while(1)
  {
    delay(2);
    Serial.println(analogRead(A0));
  }
}

void loop()
{
}

#include <Adafruit_TinyUSB.h>

void setup()
{
  Serial.begin(115200);
  Serial1.begin(115200);
  delay(1000);

  while(1)
  {
    delay(1000);
    Serial.println("USB Serial");
    Serial1.println("UART");
  }
}

void loop()
{
}

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH    (128)
#define SCREEN_HEIGHT   (64)

#define OLED_RESET      (-1)
#define SCREEN_ADDRESS  (0x3C)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
                                        
void setup()
{
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    for(;;);
  }

  display.clearDisplay();
  
  display.setTextSize(2);
  display.setTextColor(SSD1306_WHITE);

  const uint16_t posX = 20;
  const uint16_t posY = 25;

  display.setCursor(posX + 1, posY + 1);
  display.print(F("TAMANEGI"));

  display.setCursor(posX - 1, posY - 1);
  display.print(F("TAMANEGI"));

  display.setCursor(posX + 1, posY - 1);
  display.print(F("TAMANEGI"));

  display.setCursor(posX - 1, posY + 1);
  display.print(F("TAMANEGI"));

  display.setTextColor(SSD1306_BLACK);
  display.setCursor(posX, posY);
  display.print(F("TAMANEGI"));

  display.display();
}

void loop()
{
}

#include <Adafruit_GFX.h> 
#include <Adafruit_ST7735.h>
#include <SPI.h>

#define TFT_CS      (SS)
#define TFT_RST     (0)
#define TFT_DC      (1)

#define TFT_LGRAY   (0xbdf7)
#define TFT_GRAY    (0x7bef)
#define TFT_DGRAY   (0x39e7)

Adafruit_ST7735 tft = Adafruit_ST7735(&SPI, TFT_CS, TFT_DC, TFT_RST);
                                        
void setup()
{
  tft.initR(INITR_MINI160x80_PLUGIN);
  tft.fillScreen(TFT_GRAY);
  tft.setRotation(3);
  tft.setTextSize(2);

  const uint16_t posX = 30;
  const uint16_t posY = 25;

  tft.setCursor(posX + 1, posY + 1);
  tft.setTextColor(TFT_LGRAY);
  tft.printf("TAMANEGI\n");

  tft.setCursor(posX - 1, posY - 1);
  tft.setTextColor(TFT_DGRAY);
  tft.printf("TAMANEGI\n");

  tft.setCursor(posX, posY);
  tft.setTextColor(TFT_GRAY);
  tft.printf("TAMANEGI\n");

  tft.drawRect(19, 9, 119, 49, TFT_DGRAY);
  tft.drawRect(20, 10, 120, 50, TFT_LGRAY);
}

void loop()
{
}

#include <bluefruit.h>
#include <Adafruit_LittleFS.h>
#include <InternalFileSystem.h>

BLEDfu  bledfu;
BLEDis  bledis;
BLEUart bleuart;
BLEBas  blebas;

void setup()
{
  Serial.begin(115200);

#if CFG_DEBUG
  while ( !Serial ) yield();
#endif
  
  Serial.println("Bluefruit52 BLEUART Example");
  Serial.println("---------------------------\n");

  Bluefruit.autoConnLed(true);

  Bluefruit.configPrphBandwidth(BANDWIDTH_MAX);

  Bluefruit.begin();
  Bluefruit.setTxPower(4);
  Bluefruit.Periph.setConnectCallback(connect_callback);
  Bluefruit.Periph.setDisconnectCallback(disconnect_callback);

  bledfu.begin();

  bledis.setManufacturer("Adafruit Industries");
  bledis.setModel("Bluefruit Feather52");
  bledis.begin();

  bleuart.begin();

  blebas.begin();
  blebas.write(100);

  startAdv();
}

void startAdv(void)
{
  Bluefruit.Advertising.addFlags(BLE_GAP_ADV_FLAGS_LE_ONLY_GENERAL_DISC_MODE);
  Bluefruit.Advertising.addTxPower();

  Bluefruit.Advertising.addService(bleuart);

  Bluefruit.ScanResponse.addName();
  
  Bluefruit.Advertising.restartOnDisconnect(true);
  Bluefruit.Advertising.setInterval(32, 244);
  Bluefruit.Advertising.setFastTimeout(30);
  Bluefruit.Advertising.start(0);
}

void loop()
{
  while (Serial.available())
  {
    delay(2);

    uint8_t buf[64];
    int count = Serial.readBytes(buf, sizeof(buf));
    bleuart.write( buf, count );
  }

  while ( bleuart.available() )
  {
    uint8_t ch;
    ch = (uint8_t) bleuart.read();
    Serial.write(ch);
  }
}

void connect_callback(uint16_t conn_handle)
{
  BLEConnection* connection = Bluefruit.Connection(conn_handle);

  char central_name[32] = { 0 };
  connection->getPeerName(central_name, sizeof(central_name));

  Serial.print("Connected to ");
  Serial.println(central_name);
}

void disconnect_callback(uint16_t conn_handle, uint8_t reason)
{
  (void) conn_handle;
  (void) reason;

  Serial.println();
  Serial.print("Disconnected, reason = 0x"); Serial.println(reason, HEX);
}

#include <Adafruit_TinyUSB.h>
#include <bluefruit.h>
#include <Wire.h>

BLEDis bledis;
BLEHidAdafruit blehid;

#define MOUSECOUNT        (5)
#define ADC_X             (A0)
#define ADC_Y             (A1)
#define PLAY_XY           (20)
#define ADC_RESOLUSION    (3)

int16_t center_x = 0;
int16_t center_y = 0;

void setup() 
{

  Serial.begin(115200);
  delay(1000);

  pinMode(ADC_X, INPUT);
  pinMode(ADC_Y, INPUT);

  Bluefruit.begin();

  bledis.setManufacturer("Adafruit Industries");
  bledis.setModel("Bluefruit Feather 52");
  bledis.begin();

  blehid.begin();

  startAdv();

  center_x = analogRead(ADC_X);
  center_y = analogRead(ADC_Y);
}

void startAdv(void)
{  
  Bluefruit.Advertising.addFlags(BLE_GAP_ADV_FLAGS_LE_ONLY_GENERAL_DISC_MODE);
  Bluefruit.Advertising.addTxPower();
  Bluefruit.Advertising.addAppearance(BLE_APPEARANCE_HID_MOUSE);
  
  Bluefruit.Advertising.addService(blehid);
  Bluefruit.Advertising.addName();
  
  Bluefruit.Advertising.restartOnDisconnect(true);
  Bluefruit.Advertising.setInterval(32, 244);
  Bluefruit.Advertising.setFastTimeout(30);
  Bluefruit.Advertising.start(0); 
}

void loop() 
{
  int16_t move_x = 0;
  int16_t move_y = 0;
  
  int16_t x = analogRead(ADC_X);
  int16_t y = analogRead(ADC_Y);
//  Serial.printf("x = %d, y = %d\r\n", x, y);

  if(x < (center_x - PLAY_XY) || (center_x + PLAY_XY) < x)
  {
    move_x = (center_x < x) ? -MOUSECOUNT : MOUSECOUNT; 
  }

  if(y < (center_y - PLAY_XY) || (center_y + PLAY_XY) < y)
  {
    move_y = (center_y < y) ? -MOUSECOUNT : MOUSECOUNT; 
  }
  
  blehid.mouseMove(move_x, move_y);
}

#include <bluefruit.h>
#include <Wire.h>

BLEDis bledis;
BLEHidAdafruit blehid;

#define BUTTON_PIN    (12)

const char strKey[] = "Hello world";

void setup() 
{

  pinMode(BUTTON_PIN, INPUT_PULLDOWN);

  Bluefruit.begin();
  Bluefruit.setTxPower(4);
  bledis.setManufacturer("Adafruit Industries");
  bledis.setModel("Bluefruit Feather 52");
  bledis.begin();
  
  blehid.begin();

  startAdv();

  Wire.begin();
}

void startAdv(void)
{  
  Bluefruit.Advertising.addFlags(BLE_GAP_ADV_FLAGS_LE_ONLY_GENERAL_DISC_MODE);
  Bluefruit.Advertising.addTxPower();
  Bluefruit.Advertising.addAppearance(BLE_APPEARANCE_HID_KEYBOARD);
  
  Bluefruit.Advertising.addName();
  
  Bluefruit.Advertising.restartOnDisconnect(true);
  Bluefruit.Advertising.setInterval(32, 244);
  Bluefruit.Advertising.setFastTimeout(30);
  Bluefruit.Advertising.start(0);
}

void loop() 
{

  boolean bButton;
  int16_t mode = 0;
  while(1)
  {
    bButton = digitalRead(BUTTON_PIN);

    if(mode == 0)
    {
      if(digitalRead(BUTTON_PIN) == true)
      {
        delay(10);
        if(digitalRead(BUTTON_PIN) == true)
        {
          for(int16_t i = 0; i < sizeof(strKey); i ++)
          {
            blehid.keyPress(strKey[i]);
            blehid.keyRelease();
          }
          mode = 1;
        }
      }
    }
    else
    {
      if(digitalRead(BUTTON_PIN) == false)
      {
        delay(10);
        if(digitalRead(BUTTON_PIN) == false)
        {
          mode = 0;
        }
      }
    }
  }
}