【Arduino】赤外線センサアレイ(AMG8833)を使う

#include <Wire.h>
#include <Adafruit_AMG88xx.h>
#include <Adafruit_NeoPixel.h>

#define AMG8833_SDA      (4)
#define AMG8833_SCL      (5)

#define PIN_DIN_WS2812  (0)   // NeoPixel DINピン
#define WS2812_COUNT (8 * 8)  // 連結数

Adafruit_NeoPixel pixels(WS2812_COUNT, PIN_DIN_WS2812, NEO_GRB + NEO_KHZ800);

Adafruit_AMG88xx amg;

float TempArray[AMG88xx_PIXEL_ARRAY_SIZE];
uint32_t ConvertTEMP2Palette(float Temp);

void setup()
{
  // Wire.setSDA(AMG8833_SDA);
  // Wire.setSCL(AMG8833_SCL);

  pixels.begin();
  
  bool status;
    
  status = amg.begin();
  if (!status) 
  {
      Serial.println("Could not find a valid AMG88xx sensor, check wiring!");
      while (1);
  }
}

void loop()
{ 
    amg.readPixels(TempArray);

    for(int i = 1; i <= AMG88xx_PIXEL_ARRAY_SIZE; i ++)
    {
      pixels.setPixelColor((i - 1), ConvertTEMP2Palette(TempArray[(i - 1)]));
    }
    pixels.show();
    delay(100);
}

//温度に対する色(パレット情報)を返す
//Temp : 温度
//戻り値 : WS2812パレット情報
uint32_t ConvertTEMP2Palette(float Temp)
{
  //20℃から2℃温度が上昇するごとに色を変化させています。
  uint32_t retPalette = 0;
  if(Temp < 20)
  {
    retPalette = pixels.Color(0, 0, 10);
  }
  else if(Temp < 22)
  {
    retPalette = pixels.Color(0, 0, 40);
  }
  else if(Temp < 24)
  {
    retPalette = pixels.Color(0, 20, 40);
  }
  else if(Temp < 26)
  {
    retPalette = pixels.Color(0, 40, 20);
  }
  else if(Temp < 28)
  {
    retPalette = pixels.Color(0, 40, 0);
  }
  else if(Temp < 30)
  {
    retPalette = pixels.Color(20, 40, 0);
  }
  else if(Temp < 32)
  {
    retPalette = pixels.Color(40, 0, 0);
  }
  else
  {
    retPalette = pixels.Color(40, 0, 20);
  }

  return retPalette;
}