【Arduino】Bluetoothカメラシャッターを使う

#include <BLEDevice.h>
#include <BLEUtils.h>
#include <BLEScan.h>
#include <BLEClient.h>
#include <BLEAdvertisedDevice.h>

BLEScan* pBLEScan;
BLEClient* pClient;
BLERemoteCharacteristic* pRemoteCharacteristic;

static BLEUUID serviceUUID("1812");
static BLEUUID charUUID("2a4d");

bool doConnect = false;
BLEAdvertisedDevice* myDevice;

class MyAdvertisedDeviceCallbacks : public BLEAdvertisedDeviceCallbacks
{
  void onResult(BLEAdvertisedDevice advertisedDevice)
  {
    if (advertisedDevice.haveServiceUUID() && advertisedDevice.isAdvertisingService(serviceUUID)) 
    {
      Serial.println("Found The HID Keyboard");
      myDevice = new BLEAdvertisedDevice(advertisedDevice);
      doConnect = true;
      pBLEScan->stop();
    }
  }
};


void setup()
{
  Serial.begin(115200);
  BLEDevice::init("");

  pBLEScan = BLEDevice::getScan();
  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks());
  pBLEScan->setActiveScan(true);
  pBLEScan->start(10, false);
}

void loop()
{
  if (doConnect)
  {
    pClient = BLEDevice::createClient();
    pClient->connect(myDevice);
    Serial.print("Connected : ");
    Serial.println(myDevice->getAddress().toString().c_str());

    BLERemoteService* pRemoteService = pClient->getService(serviceUUID);
    if (pRemoteService == nullptr)
    {
      Serial.println("Not found service.");
      return;
    }

    pRemoteCharacteristic = pRemoteService->getCharacteristic(charUUID);
    if (pRemoteCharacteristic == nullptr)
    {
      Serial.println("Not found characteristic");
      return;
    }
pRemoteCharacteristic->registerForNotify(
  [](BLERemoteCharacteristic* pBLERemoteCharacteristic, uint8_t* pData, size_t length, bool isNotify) {
    Serial.print("Received: ");
    for (int i = 0; i < length; i++)
    {
      Serial.printf("%02X ", pData[i]);
    }
    Serial.println();
  }
);
    doConnect = false;
  }

  delay(1000);
}