【電子工作】ハンドスピナー回転測定器を作る

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include "pico/stdlib.h"

#define SSD1306_SDA         (0)
#define SSD1306_SCL         (1)
#define SSD1306_RESET       (-1)               //使用しないので　-1を設定する。
#define SSD1306_ADDRESS     (0x3C)             //I2Cアドレスは 0x3C
#define SSD1306_WIDTH       (128)              //解像度 128 x 64 で使用します。
#define SSD1306_HEIGHT      (64)

#define SENSOR_PIN          (2)               //センサーピン

#define TIME_1SECOND        (1000000)         //1s = 1,000,000us
bool timer_Measurement( repeating_timer_t *rt);

Adafruit_SSD1306 display(SSD1306_WIDTH, SSD1306_HEIGHT, &Wire, SSD1306_RESET);     //I2C0を使用する


u_int8_t FlagStat = LOW;                //最後に読み取ったセンサーの状態
long HIGHCounter = 0;                   //センサーの反応回数
u_int32_t After1s_us;

void setup() {
  //センサーのピン設定
  pinMode(SENSOR_PIN, INPUT_PULLDOWN);

  //OLEDピン設定
  Wire.setSDA(SSD1306_SDA);
  Wire.setSCL(SSD1306_SCL);
  
  if(!display.begin(SSD1306_SWITCHCAPVCC, SSD1306_ADDRESS)) {
    for(;;);
  }

  After1s_us = time_us_32() + TIME_1SECOND;
}

void loop() {
  u_int8_t Dat = digitalRead(SENSOR_PIN);         //センサーの状態を読み取る

  //1.センサーの状態確認とカウンターの更新

  //センサーの状態がHIGHならカウントアップ
  //次の周回で状態がLOWになるまでカウントは変化しない。
  if(FlagStat == LOW) {
    if(Dat == HIGH) {
      HIGHCounter ++;
      FlagStat = HIGH;
    }
  }
  else {
    //センサーHIGH待機状態に更新
    if(Dat == LOW) {
      FlagStat = LOW;
    }
  }

  //2.１秒経過確認
  u_int32_t now_us = time_us_32();        //起動からの時間読み取り(us)

  if(After1s_us < now_us) {
    //情報の更新
    display.clearDisplay();
    display.setTextSize(2);
    display.setCursor(0, 0);
    display.setTextColor(SSD1306_WHITE);
    display.printf("%ld times", HIGHCounter);
    display.display();                    //バッファ転送（表示)

    HIGHCounter = 0;                      //カウンタクリア
    After1s_us = now_us + TIME_1SECOND;   //次の1秒設定
  }
}